بسم الله الرحمن الرحيم

تحليل او تفكيك المتسلسلة الي مركبات Decomposition Method :

البيانات التالية إنتاج 168 يوما للحليب في أحد المزارع بالكيلو جرام

MTB > Read "E:\Mtbwin\milk.dat" c1.

Entering data from file: E:\Mtbwin\milk.dat

168 rows read.

MTB > name c1='MilkProd'

MTB > print c1

Data Display

 

MilkProd

589 561 640 656 727 697 640 599 568 577 553 582 600 566 653 673 742 716 660 617 583 587 565 598 628 618 688 705 770 736 678 639 604 611 594 634 658 622 709 722 782 756

702 653 615 621 602 635 677 635 736 755 811 798 735 697 661 667 645 688 713 667 762 784 837 817 767 722 681 687 660 698 717 696 775 796 858 826 783 740 701 706 677 711

734 690 785 805 871 845 801 764 725 723 690 734 750 707 807 824 886 859 819 783 740 747 711 751 804 756 860 878 942 913 869 834 790 800 763 800 826 799 890 900 961 935

894 855 809 810 766 805 821 773 883 898 957 924 881 837 784 791 760 802 828 778 889 902 969 947 908 867 815 812 773 813 834 782 892 903 966 937 896 858 817 827 797 843

MTB >

ونرسم البيانات السابقة بالآوامر:

MTB > TSPlot 'MilkProd';

SUBC> Index;

SUBC> TDisplay 11;

SUBC> Symbol;

SUBC> Connect.

MTB >

 

 

أحد الطرق للتنبؤ لمتسلسلات من هذا الشكل هو تفكيكها الى مركبات كالتالي:

نفترض ان لدينا المشاهدات والتي يمكن تمثيلها كالتالي

حيث هي مركبة الانجراف و مركبة الموسمية و المركبة الدورية و مركبة الخطأ

النموذج الاول يسمى بالنموذج الإضافي Additive Model و النموذج الثاني يسمي النموذج الضربي Multiplicative Model في هذا المستوى سوف نهمل المركبة الدورية ونكتفي بالنماذج علي الشكل

أنظر كتاب FORECASTING: METHODS AND APPLICATIONS للمؤلفين MAKRIDAKIS/ WHEELWRIGHT/ McGEE ص 131-141

اولا: تطبيق النموذج الإضافي:

لمشاهدات نكتب النموذج على الشكل لكي نقوم بتفكيك هذه المتسلسلة الزمنية الي المركبات السابقة سوف نستعرض ثلاثة طرق ممكنة:

الطريقة الاولي:

  1. نطبق إنحدار خطي بسيط للمشاهدات علي الزمن لتقدير مركبة الانجراف أي:
  2. أي:

    MTB > set c2

    DATA> 1:168

    DATA> end

    MTB > name c1='MilkProd' c2='Time' c3='Trend' c5='Detrend' c6='Index' c8='Fitted' c9='Resid'

    MTB > regr c1 1 c2;

    SUBC> fits c3.

    Regression Analysis

     

    The regression equation is

    MilkProd = 612 + 1.69 Time

    Predictor Coef StDev T P

    Constant 611.682 9.414 64.97 0.000

    Time 1.69262 0.09663 17.52 0.000

    S = 60.74 R-Sq = 64.9% R-Sq(adj) = 64.7%

    Analysis of Variance

    Source DF SS MS F P

    Regression 1 1132003 1132003 306.83 0.000

    Error 166 612439 3689

    Total 167 1744443

    Unusual Observations

    Obs Time MilkProd Fit StDev Fit Residual St Resid

    113 113 942.00 802.95 5.44 139.05 2.30R

    125 125 961.00 823.26 6.11 137.74 2.28R

    R denotes an observation with a large standardized residual

    MTB >

    وشكل الإنجراف هو

     

     

  3. نطرح مركبة الإنجراف من المشاهدات الاصلية فنحصل علي مايسمي بالمتسلسلة مزالة الإنجراف Detrended Series أي
  4. MTB > let c5=c1-c3

    ولها الشكل التالي:

     

    نلاحظ انها اصبحت موسمية فقط لأن

  5. لتقدير المركبة الموسمية نوجد المؤشرات الموسمية Seasonal Indices كالتالي:
  6. لنرمز للمؤشرات الموسمية بالرمز حيث المؤشر الموسمي للشهر الأول و المؤشر الموسمي للشهر الثاني وهكذا ولنرمز بـ تقدر هذه المؤشرات كالتالي:

    ويتم ذلك بإستخدام الأوامر التالية:

    MTB > set c4

    DATA> 14(1:12)

    DATA> end

    MTB > stat c5;

    SUBC> by c4;

    SUBC> mean c6.

    MTB > Stack 'Index' 'Index' 'Index' 'Index' 'Index' 'Index' 'Index' &

    CONT> 'Index' 'Index' 'Index' 'Index' 'Index' 'Index' 'Index' c7.

    MTB > let c8=c3+c7

    MTB > let c9=c1-c8

    MTB > set c10

    DATA> 1:12

    DATA> end

    MTB > print c10 c6

    Data Display

     

    Row Season Index

    1 1 -18.328

    2 2 -57.806

    3 3 34.716

    4 4 49.595

    5 5 110.616

    6 6 82.281

    7 7 32.517

    8 8 -9.747

    9 9 -52.297

    10 10 -48.775

    11 11 -79.754

    12 12 -43.018

    MTB >

  7. التنبؤات تولد كالتالي:

فمثلا التنبؤ عند اليوم 169 هو

الطريقة الثانية:

وهي التي يستخدمها برنامج Minitab :

  1. كالطريقة الاولى نطبق إنحدار خطي بسيط للمشاهدات علي الزمن لتقدير مركبة الانجراف فنحصل على نفس النتيجة كما في الطريقة الاولى (1)
  2. ايضا هنا نطرح مركبة الإنجراف من المشاهدات الاصلية فنحصل علي المتسلسلة مزالة الإنجراف Detrended Series
  3. نطبق الآن متوسط متحرك من درجة الموسم ونوسطه اذا احتاج الامر
  4. نطرح المتوسطات المتحركة من نظيراتها في المتسلسلة مزالة الإنجراف فنحصل علي متسلسلة تحوي المركبات الموسمية
  5. تقدر المركبات الموسمية كالتالي:
  6. تولد التنبؤات كالسابق

وسوف نستعرض هذا كالتالي:

MTB > Read "E:\Mtbwin\milk.dat" c1.

Entering data from file: E:\Mtbwin\milk.dat

168 rows read.

MTB > name c1='MilkProd'

MTB > set c2

DATA> 1:168

DATA> end

MTB > name c2='Time'

MTB > regr c1 1 c2;

SUBC> fits c3.

Regression Analysis

 

The regression equation is

MilkProd = 612 + 1.69 Time

Predictor Coef StDev T P

Constant 611.682 9.414 64.97 0.000

Time 1.69262 0.09663 17.52 0.000

S = 60.74 R-Sq = 64.9% R-Sq(adj) = 64.7%

Analysis of Variance

Source DF SS MS F P

Regression 1 1132003 1132003 306.83 0.000

Error 166 612439 3689

Total 167 1744443

Unusual Observations

Obs Time MilkProd Fit StDev Fit Residual St Resid

113 113 942.00 802.95 5.44 139.05 2.30R

125 125 961.00 823.26 6.11 137.74 2.28R

R denotes an observation with a large standardized residual

MTB > name c3='Trend'

MTB > let c4=c1-c3

MTB > name c4='Detrend'

MTB > Name c5 = 'AVER1'

في الخطوة التالية نطبق متوسط متحرك من الدرجة 12 ونوسطه:

MTB > %MA 'Detrend' 12;

SUBC> Center;

SUBC> Averages 'AVER1'.

Executing from file: E:\MTBWIN\MACROS\MA.MAC

Macro is running ... please wait

Moving average

Data Detrend

Length 168.000

NMissing 0

Moving Average

Length: 12

Accuracy Measures

MAPE: 111.68

MAD: 52.36

MSD: 3564.77

نطرح المتوسطات المتحركة الموسطة من المتسلسلة المزال إنجرافها

MTB > let c6=c4-c5

MTB > name c6='DeSeason'

MTB > set c2

DATA> 14(1:12)

DATA> end

MTB > stat c6;

SUBC> by c2;

SUBC> median c7.

MTB > name c7='SeasInx'

Data Display

 

Row Season SeasInx

1 1 -20.750

2 2 -58.958

3 3 35.625

4 4 50.083

5 5 109.542

6 6 81.292

7 7 33.917

8 8 -10.000

9 9 -52.792

10 10 -50.250

11 11 -7.958

12 12 -44.375

نقارن الحسابات التي اجريناها مع البرنامج الأصلي:

MTB > %Decomp 'MilkProd' 12;

SUBC> Additive ;

SUBC> Start 1.

Executing from file: E:\MTBWIN\MACROS\Decomp.MAC

Macro is running ... please wait

Time Series Decomposition

Data MilkProd

Length 168.000

NMissing 0

Trend Line Equation

Yt = 611.682 + 1.69262*t

Seasonal Indices

Period Index

1 -20.1979

2 -58.4062

3 36.1771

4 50.6354

5 110.094

6 81.8437

7 34.4687

8 -9.44792

9 -52.2396

10 -49.6979

11 -79.4063

12 -43.8229

Accuracy of Model

MAPE: 1.583

MAD: 12.088

MSD: 244.406

MTB >

وبمقارنة النتيجتين نجد انهما تقريبا متساويتان.

سوف نولد تنبؤات باستخدام البرنامج %Decomp كالتالي:

MTB > %Decomp 'MilkProd' 12;

SUBC> Additive ;

SUBC> Forecasts 12;

SUBC> Start 1.

والتي تعطي التنبؤات:

Forecasts

Row Period Forecast

1 169 877.54

2 170 841.02

3 171 937.30

4 172 953.45

5 173 1014.60

6 174 988.04

7 175 942.36

8 176 900.13

9 177 859.04

10 178 863.27

11 179 835.25

12 180 872.53

تمرين: ولد تنبؤات لإنتاج الحليب اليومي بإستخدام الطريقتين المعطاة وقارنها بالقيم الأخيرة الناتجة من البرنامج